Scoring and Scoreboard implemented

modes/multiplayer.tscn

@@ -1,8 +1,9 @@
-[gd_scene load_steps=5 format=3 uid="uid://bvwxfgygm2xb8"]
+[gd_scene load_steps=6 format=3 uid="uid://bvwxfgygm2xb8"]
 
 [ext_resource type="PackedScene" uid="uid://chbno00ugl6te" path="res://maps/genesis/genesis.tscn" id="1_nulvv"]
 [ext_resource type="PackedScene" uid="uid://cbhx1xme0sb7k" path="res://entities/player/player.tscn" id="2_og1vb"]
 [ext_resource type="PackedScene" uid="uid://c88l3h0ph00c7" path="res://entities/flag/flag.tscn" id="3_h0rie"]
+[ext_resource type="Script" path="res://modes/scoreboard.gd" id="4_n0mhp"]
 
 [sub_resource type="GDScript" id="GDScript_1qrbp"]
 script/source = "class_name Multiplayer extends Node
@@ -16,6 +17,8 @@ script/source = "class_name Multiplayer extends Node
 @onready var players : Node = $Players
 @onready var objectives : Node = $Objectives
 @onready var map : Node = $Map
+@onready var scoreboard : Scoreboard = $Scoreboard
+@onready var scoreboard_ui : Node = $ScoreboardUI
 
 var _map_manager : Map
 
@@ -33,7 +36,7 @@ func start_server(port : int, nickname : String) -> void:
 	multiplayer.peer_disconnected.connect(remove_player)
 
 func join_server(host : String, port : int, nickname : String) -> void:
-	var peer : ENetMultiplayerPeer= ENetMultiplayerPeer.new()
+	var peer : ENetMultiplayerPeer = ENetMultiplayerPeer.new()
 	peer.create_client(host, port)
 	multiplayer.connected_to_server.connect(_on_connected_to_server.bind(nickname))
 	multiplayer.connection_failed.connect(_on_connection_failed)
@@ -41,12 +44,20 @@ func join_server(host : String, port : int, nickname : String) -> void:
 
 func _on_connected_to_server(nickname : String) -> void:
 	connected_to_server.emit()
+	scoreboard.request_scoreboard_from_authority.rpc()
 	_join_match.rpc(nickname)
 
 func _on_connection_failed() -> void:
 	connection_failed.emit()
 
-func respawn_player(player : Player) -> void:
+func respawn_player(player : Player, killer_id : int) -> void:
+	if player.player_id != killer_id:
+		var node_name : String = str(killer_id)
+		if players.has_node(node_name):
+			var killer : Player = players.get_node(node_name)
+			scoreboard.increment_kill_count(killer)
+			scoreboard.add_score_to_player(killer, 10)
+			scoreboard.broadcast_player_score_update(killer)
 	var spawn_location : Vector3 = _map_manager.get_player_spawn().position
 	player.respawn(spawn_location)
 
@@ -58,13 +69,15 @@ func add_player(peer_id : int, nickname : String) -> void:
 	player.global_position = _map_manager.get_player_spawn().position
 	players.add_child(player)
 	player.died.connect(respawn_player)
+	scoreboard.add_entry(player)
 	print(\"Peer `%s` connected\" % player.name)
 
 func remove_player(peer_id : int) -> void:
 	var node_name : String = str(peer_id)
 	if players.has_node(node_name):
 		var player : Player = players.get_node(node_name)
-		player.die()
+		scoreboard.remove_entry(player)
+		player.die(-1)
 		player.queue_free()
 		print(\"Peer `%s` disconnected\" % node_name)
 
@@ -81,6 +94,19 @@ func _add_flag() -> void:
 	flag.global_position = _map_manager.get_flagstand().global_position
 	objectives.add_child(flag)
 
+func _unhandled_input(event : InputEvent) -> void:
+	if event.is_action_pressed(\"scoreboard\"):
+		var entries : Array = scoreboard.get_entries()
+		for entry : Scoreboard.ScoreboardEntry in entries:
+			var entry_label : Label = Label.new()
+			entry_label.text = \"%s | kills: %s | score: %s\" % [entry.nickname, entry.kills, entry.score]
+			%Scores.add_child(entry_label)
+		scoreboard_ui.show()
+	elif event.is_action_released(\"scoreboard\"):
+		scoreboard_ui.hide()
+		for score_label in %Scores.get_children():
+			score_label.queue_free()
+
 @rpc(\"any_peer\")
 func _join_match(nickname : String) -> void:
 	if is_multiplayer_authority():
@@ -115,3 +141,36 @@ spawn_path = NodePath("../Players")
 [node name="ObjectivesSpawner" type="MultiplayerSpawner" parent="."]
 _spawnable_scenes = PackedStringArray("res://entities/flag/flag.tscn")
 spawn_path = NodePath("../Objectives")
+
+[node name="Scoreboard" type="Node" parent="."]
+script = ExtResource("4_n0mhp")
+
+[node name="ScoreboardUI" type="Control" parent="."]
+visible = false
+layout_mode = 3
+anchors_preset = 15
+anchor_right = 1.0
+anchor_bottom = 1.0
+grow_horizontal = 2
+grow_vertical = 2
+
+[node name="PanelContainer" type="PanelContainer" parent="ScoreboardUI"]
+layout_mode = 1
+anchors_preset = 15
+anchor_right = 1.0
+anchor_bottom = 1.0
+grow_horizontal = 2
+grow_vertical = 2
+
+[node name="VBoxContainer" type="VBoxContainer" parent="ScoreboardUI/PanelContainer"]
+layout_mode = 2
+size_flags_horizontal = 4
+size_flags_vertical = 0
+
+[node name="Label" type="Label" parent="ScoreboardUI/PanelContainer/VBoxContainer"]
+layout_mode = 2
+text = "Scoreboard"
+
+[node name="Scores" type="VBoxContainer" parent="ScoreboardUI/PanelContainer/VBoxContainer"]
+unique_name_in_owner = true
+layout_mode = 2

modes/scoreboard.gd

@@ -0,0 +1,77 @@
+# This file is part of open-fpsz.
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation, either version 3 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, see <https://www.gnu.org/licenses/>.
+class_name Scoreboard extends Node
+
+@export var _entries : Dictionary = {}
+
+class ScoreboardEntry:
+	var nickname : String
+	var kills : int
+	var score : int
+
+func add_entry(player : Player) -> void:
+	var new_entry : ScoreboardEntry = ScoreboardEntry.new()
+	new_entry.nickname = player.nickname
+	new_entry.kills = 0
+	new_entry.score = 0
+	_entries[player.player_id] = new_entry
+	_send_scoreboard_entry.rpc(player.player_id, new_entry.nickname, new_entry.kills, new_entry.score)
+
+func remove_entry(player : Player) -> void:
+	_entries.erase(player.player_id)
+	_broadcast_player_removed(player)
+
+func add_score_to_player(player : Player, amount : int) -> void:
+	_entries[player.player_id].score += amount
+
+func increment_kill_count(player : Player) -> void:
+	_entries[player.player_id].kills += 1
+
+func get_entries() -> Array:
+	return _entries.values()
+
+@rpc("any_peer", "call_remote", "reliable")
+func request_scoreboard_from_authority() -> void:
+	if is_multiplayer_authority():
+		var recipient_id : int = multiplayer.get_remote_sender_id()
+		_clear_scoreboard.rpc_id(recipient_id)
+		for entry_key : int in _entries:
+			var entry : ScoreboardEntry = _entries[entry_key]
+			_send_scoreboard_entry.rpc_id(recipient_id, entry_key, entry.nickname, entry.kills, entry.score)
+
+@rpc("authority", "reliable")
+func _clear_scoreboard() -> void:
+	_entries.clear()
+
+@rpc("authority", "reliable")
+func _send_scoreboard_entry(player_id : int, nickname : String, kills : int, score : int) -> void:
+	var new_entry : ScoreboardEntry = ScoreboardEntry.new()
+	new_entry.nickname = nickname
+	new_entry.kills = kills
+	new_entry.score = score
+	_entries[player_id] = new_entry
+
+@rpc("authority", "reliable")
+func _remove_scoreboard_entry(player_id : int) -> void:
+	_entries.erase(player_id)
+
+func broadcast_player_score_update(player : Player) -> void:
+	var player_id : int = player.player_id
+	var player_score_entry : ScoreboardEntry = _entries[player_id]
+	_send_scoreboard_entry.rpc(player_id, player_score_entry.nickname, player_score_entry.kills, player_score_entry.score)
+
+func _broadcast_player_removed(player : Player) -> void:
+	var player_id : int = player.player_id
+	_remove_scoreboard_entry.rpc(player_id)