open-fpsz/modes/multiplayer.tscn

[gd_scene load_steps=6 format=3 uid="uid://bvwxfgygm2xb8"]

[ext_resource type="PackedScene" uid="uid://chbno00ugl6te" path="res://maps/genesis/genesis.tscn" id="1_nulvv"]
[ext_resource type="PackedScene" uid="uid://cbhx1xme0sb7k" path="res://entities/player/player.tscn" id="2_og1vb"]
[ext_resource type="PackedScene" uid="uid://c88l3h0ph00c7" path="res://entities/flag/flag.tscn" id="3_h0rie"]
[ext_resource type="Script" path="res://modes/scoreboard.gd" id="4_n0mhp"]

[sub_resource type="GDScript" id="GDScript_1qrbp"]
script/source = "class_name Multiplayer extends Node

@export_category(\"Parameters\")
@export var MAP : PackedScene
@export var PLAYER : PackedScene
@export var FLAG : PackedScene
@export var MAX_CLIENTS : int = 24

@onready var players : Node = $Players
@onready var objectives : Node = $Objectives
@onready var map : Node = $Map
@onready var scoreboard : Scoreboard = $Scoreboard
@onready var scoreboard_ui : Node = $ScoreboardUI

var _map_manager : Map

signal connected_to_server
signal connection_failed

func start_server(port : int, nickname : String) -> void:
	var peer : ENetMultiplayerPeer = ENetMultiplayerPeer.new()
	peer.create_server(port, MAX_CLIENTS)

	multiplayer.multiplayer_peer = peer

	_load_map.call_deferred(MAP, nickname)

	multiplayer.peer_disconnected.connect(remove_player)

func join_server(host : String, port : int, nickname : String) -> void:
	var peer : ENetMultiplayerPeer = ENetMultiplayerPeer.new()
	peer.create_client(host, port)
	multiplayer.connected_to_server.connect(_on_connected_to_server.bind(nickname))
	multiplayer.connection_failed.connect(_on_connection_failed)
	multiplayer.multiplayer_peer = peer

func _on_connected_to_server(nickname : String) -> void:
	connected_to_server.emit()
	scoreboard.request_scoreboard_from_authority.rpc()
	_join_match.rpc(nickname)

func _on_connection_failed() -> void:
	connection_failed.emit()

func respawn_player(player : Player, killer_id : int) -> void:
	if player.player_id != killer_id:
		var node_name : String = str(killer_id)
		if players.has_node(node_name):
			var killer : Player = players.get_node(node_name)
			scoreboard.increment_kill_count(killer)
			scoreboard.add_score_to_player(killer, 10)
			scoreboard.broadcast_player_score_update(killer)
	var spawn_location : Vector3 = _map_manager.get_player_spawn().position
	player.respawn(spawn_location)

func add_player(peer_id : int, nickname : String) -> void:
	var player : Player = PLAYER.instantiate()
	player.name = str(peer_id)
	player.player_id = peer_id
	player.nickname = nickname
	player.global_position = _map_manager.get_player_spawn().position
	players.add_child(player)
	player.died.connect(respawn_player)
	scoreboard.add_entry(player)
	print(\"Peer `%s` connected\" % player.name)

func remove_player(peer_id : int) -> void:
	var node_name : String = str(peer_id)
	if players.has_node(node_name):
		var player : Player = players.get_node(node_name)
		scoreboard.remove_entry(player)
		player.die(-1)
		player.queue_free()
		print(\"Peer `%s` disconnected\" % node_name)

func _load_map(scene : PackedScene, nickname : String) -> void:
	var map_scene : Node = scene.instantiate()
	_map_manager = map_scene
	map_scene.ready.connect(_add_flag)
	if DisplayServer.get_name() != \"headless\":
		add_player(1, nickname)
	map.add_child(map_scene)

func _add_flag() -> void:
	var flag : Flag = FLAG.instantiate()
	flag.global_position = _map_manager.get_flagstand().global_position
	objectives.add_child(flag)

func _unhandled_input(event : InputEvent) -> void:
	if event.is_action_pressed(\"scoreboard\"):
		var entries : Array = scoreboard.get_entries()
		for entry : Scoreboard.ScoreboardEntry in entries:
			var entry_label : Label = Label.new()
			entry_label.text = \"%s | kills: %s | score: %s\" % [entry.nickname, entry.kills, entry.score]
			%Scores.add_child(entry_label)
		scoreboard_ui.show()
	elif event.is_action_released(\"scoreboard\"):
		scoreboard_ui.hide()
		for score_label in %Scores.get_children():
			score_label.queue_free()

@rpc(\"any_peer\")
func _join_match(nickname : String) -> void:
	if is_multiplayer_authority():
		add_player(multiplayer.get_remote_sender_id(), nickname)

func _exit_tree() -> void:
	if is_multiplayer_authority():
		multiplayer.peer_disconnected.disconnect(remove_player)
"

[node name="Multiplayer" type="Node"]
script = SubResource("GDScript_1qrbp")
MAP = ExtResource("1_nulvv")
PLAYER = ExtResource("2_og1vb")
FLAG = ExtResource("3_h0rie")

[node name="Map" type="Node" parent="."]

[node name="MapSpawner" type="MultiplayerSpawner" parent="."]
_spawnable_scenes = PackedStringArray("res://maps/genesis/genesis.tscn")
spawn_path = NodePath("../Map")
spawn_limit = 1

[node name="Players" type="Node" parent="."]

[node name="PlayersSpawner" type="MultiplayerSpawner" parent="."]
_spawnable_scenes = PackedStringArray("res://entities/player/player.tscn")
spawn_path = NodePath("../Players")

[node name="Objectives" type="Node" parent="."]

[node name="ObjectivesSpawner" type="MultiplayerSpawner" parent="."]
_spawnable_scenes = PackedStringArray("res://entities/flag/flag.tscn")
spawn_path = NodePath("../Objectives")

[node name="Scoreboard" type="Node" parent="."]
script = ExtResource("4_n0mhp")

[node name="ScoreboardUI" type="Control" parent="."]
visible = false
layout_mode = 3
anchors_preset = 15
anchor_right = 1.0
anchor_bottom = 1.0
grow_horizontal = 2
grow_vertical = 2

[node name="PanelContainer" type="PanelContainer" parent="ScoreboardUI"]
layout_mode = 1
anchors_preset = 15
anchor_right = 1.0
anchor_bottom = 1.0
grow_horizontal = 2
grow_vertical = 2

[node name="VBoxContainer" type="VBoxContainer" parent="ScoreboardUI/PanelContainer"]
layout_mode = 2
size_flags_horizontal = 4
size_flags_vertical = 0

[node name="Label" type="Label" parent="ScoreboardUI/PanelContainer/VBoxContainer"]
layout_mode = 2
text = "Scoreboard"

[node name="Scores" type="VBoxContainer" parent="ScoreboardUI/PanelContainer/VBoxContainer"]
unique_name_in_owner = true
layout_mode = 2